Диспетчер скриптов mIRC — различия между версиями

Материал из IrcNet.ru Wiki
Перейти к: навигация, поиск
(Внешний вид)
Строка 16: Строка 16:
  
 
==Внешний вид==
 
==Внешний вид==
 +
[[Файл:Sd.jpg]]
  
 
==Установка==
 
==Установка==

Версия 13:26, 15 декабря 2009

Диспетчер скриптов mIRC, 0.1

Распространяется под лицензией GPL v2 (Текст лицензии)

Автор Siniy

Основные функции

  • Отображение загруженных скриптов
  • Отображение файлов в папке по определенной маске (по умолчанию папка scripts и маска *.mrc)
  • Загрузка скриптов
  • Выгрузка скриптов
  • Просмотр загруженного скрипта

История изменений

v 0.1 Первая публичная версия скрипта

Внешний вид

Sd.jpg

Установка

Положить в папку с mIRC.exe или в папку scripts. В первом случае выполнить

/load -rs scripts.mrc 

Во втором

/load -rs scripts/scripts.mrc

Использование

Нажимать на меню "Управление скриптами" в окне статуса (правой кнопкой в окне статуса), либо набираем команду /sd

Скачать

Форум


Код

;----------------------------------------------
;   Диспетчер скриптов mIRC, 0.1
; 
;----------------------------------------------
;   (с) Alexandr Sinitsyn aka Siniy
;   irc: Siniy @ irc.ircnet.su, 2008 
;   http://www.siniy.ws/
;   mailto: alsinit@gmail.com 
;----------------------------------------------
;   Использование:
;    Положить в папку с mIRC.exe или в папку scripts
;   /load -rs scripts.mrc (или /load -rs scripts/scripts.mrc смотря куда положили)
;----------------------------------------------
 
 menu status {
  Управление скриптами { /dialog -m scripts scripts }
 }
 alias /sd /dialog -m scripts scripts
 dialog scripts {
  size -1 -1 200 152
  option dbu
  Title "Управление скриптами"
  button "Перезагрузить", 1, 2 2 40 10
  button "Просмотр", 2, 54 2 40 10
  button "Загрузить", 9, 106 2 40 10
  button "Выгрузить", 4, 158 2 40 10
  button "Выбрать", 12, 158 18 40 10
  list 5, 0 40 100 130, autovs
  list 10, 100 40 100 130, autovs
  text "Всего загружено: ", 6, 3 30 60 10
  text "Содержимое папки:", 11, 103 30 60 10
  text $script(0) , 7, 55 30 20 10
  edit %currdir, 8, 2 18 150 10, read
  edit %currmask, 13, 170 30 30 10
}
;Функции
;Рефреш левого листа
alias left_refresh {
  did -r scripts 5
  set %total.scripts $script(0)
  set %c 1
  while (%c <= %total.scripts) {
    did -a scripts 5 $script(%c)
    inc %c 1
  }
}
;Рефреш правого листа
alias right_refresh {
  did -r scripts 10
  set %i 1
  while ($findfile(%currdir,%currmask,%i) != $null) {
  did -a scripts 10 $findfile(%currdir,%currmask,%i)
  inc %i 1
  }
}
;Инициализация
on *:DIALOG:scripts:init:*: { 
  left_refresh
  set %currdir [ [ $mircdir ] $+ ] scripts\
  set %currmask *.mrc
  right_refresh
  did -b scripts 2,4,1
}
;Нажатие на контролы
on *:DIALOG:scripts:sclick:*: {
  if ($did == 1) {
    load -rs " $+ $did(5).seltext $+ "
  }
;Кнопка Загрузить
  if ($did == 9) {
    load -rs " $+ $did(10).seltext $+ "
    did -b scripts 2,4
    did -a scripts 7 $script(0)
    left_refresh
  }
;Выбор из левого листа
  if ($did == 5) {
    did -e scripts 2,4,1
  }
;Выбор из правого листа
  if ($did == 10) {
    did -e scripts 2,4,1
  }
;Кнопка Открыть
  if ($did == 2) {
    run $did(5).seltext
  }
;Кнопка Выгрузить
  if ($did == 4) {
    unload -rs " $+ $did(5).seltext $+ "
    did -r scripts 5
    did -b scripts 2,4,1
    did -a scripts 7 $script(0)
    left_refresh
  }
;Кнопка Выбрать
  if ($did == 12) {
  set %currdir $sdir(%currdir,"Выберите папку со скриптами")
  did -r scripts 8
  did -a scripts 8 %currdir
  right_refresh
  }
 
}
;Изменение маски
on *:DIALOG:scripts:EDIT:13: { 
set %currmask $did(13).text
right_refresh
}